Script to list the number of SQL PI agents assigned to each Fglam and PI repository (4226978)

The following script can be run in the script console to list the SQL PI agents and their PI repositories and Agent Managers.

1. Navigate to Administration | Tooling | Script Console.
2. Select the Scripts tab
3. Click the Add button
4. Paste the script text from below into the dialog box
5. (optional) Enter a title for the script
6. (optional) Click the Save button to save the script in the FMS
7. Click the Run button
8. Select Log Messages tab
9. Copy the output and paste the results into a text editor.

piRepositories = [:];
agentService = server.get("AgentService");
configService = server.get("ConfigService");
agentMgmntService = server.get("RemoteAgentManagementService");

fglAMId2NameMap = agentMgmntService.findAllRemoteClients().collectEntries {
    [(it.id) : it.hostName]
}

//MsSql
fillAgents("DB_SQL_Server", "paecEnable", "parcStorageHost");

//Oracle
fillAgents("DB_Oracle", "spiecEnable", "spircStorageHost");

//AzureSQL
fillAgents("DB_Azure_Database", "paecEnable", "parcStorageHost");

//MySQLPI
fillAgents("DB_MySQL_PI", "paecEnable", "parcStorageHost");


// print out
def output = piRepositories.collect { k, v ->
"""
${k}    ${v.get("totalAgents")}
${v.get("distribution").collect{ fglam, agents ->
"""++++++++${fglam}    ${agents.size()}
++++++++++++++++${agents.join("\n++++++++++++++++")}
"""
}.join("\n")}
"""
}.join("--------------------------------\n");

println output

return piRepositories;

def fillAgents(agentType, flagAsp, hostAsp) {
     def agents = agentService.findByAdapterAndType("FglAM", agentType);
     for (agent in agents) {
           def primaryASP = configService.getAgentInstancePrimaryAsp(agent.getAgentNamespace(), agent.getTypeId(), agent.getId());
           if (primaryASP && primaryASP.getBoolean(flagAsp)) {
                def piHost = primaryASP.getString(hostAsp);
                def fglAMHost = fglAMId2NameMap.get(agent.getRemoteClientId());
                
                def piHostMap = piRepositories.get(piHost)?:["totalAgents":0, "distribution": [:]];
                
                piRepositories.put(piHost, piHostMap)
                
                // count all agents in same PI
                def agentsList = piHostMap.get("distribution").get(fglAMHost);
                if (agentsList == null) {
                      agentsList = [];
                      piHostMap.get("distribution").put(fglAMHost, agentsList);
                }                                                           
                agentsList.add(agent.getName());
                piHostMap.put("totalAgents", piHostMap.get("totalAgents") + 1)
           }
     }
}

• The lines followed by a number represent the PI Agent Manager, with the number of total agents using that PI FglAM
• The lines preceded by ++++++++ are the agent managers where the database agents are installed, followed by the number of database agents with PI
• The lines preceded by ++++++++++++++++ are each of the database agents with the PI extension enabled using those agent managers