How to setup add an ignore list entry for the DB2 diagnostic log to all DB2 agents? (4227489)

WORKAROUND

1. Change the variable values in the script
2. Run the groovy script using the FMS "Script Console" panel.
   
3. In the DB2 Administration | Diagnostic Log panel, click the "Assign Ignore List Group" button to verify whether the row have been added into the Ignore List of not.
   
   

The groovy script is as follows

ignore_filterName = "custom-ignore-list-000"//customer input it
ignore_fieldName = "Severity"//The value should be 1 of: "Severity", "Message", "Type", "Impact", "Component", "Function", "Fullrec"
ignore_expression = "custom-ignore-expression-000"//customer input it

output = new StringBuilder()
configService = server.get("ConfigService");
IGNORE_LIST_GROUP_ID = "lmdIgnoreList";

if (validateInput()) {
	addIntoIgnoreList()
}
return output.toString()

def validateInput() {
	if (!(ignore_fieldName in ["Severity", "Message", "Type", "Impact", "Component", "Function", "Fullrec"])) {
		log("!!!Please input a valid \"ignore_fieldName\", its value should be 1 of: \"Severity\", \"Message\", \"Type\", \"Impact\", \"Component\", \"Function\", \"Fullrec\".")
		return false
	}
	return true
}

def addIntoIgnoreList() {
	def knownNames = getIgnoreListKnownNames()
	knownNames.each { knownName ->
		addRowItem(knownName)
	}
}

def addRowItem(knownName) {
	def secondaryAsp = configService.getSecondaryAsp("DB_DB2", "DB_DB2", IGNORE_LIST_GROUP_ID, knownName)
	log("addRowItem: knownName:${knownName}, secondaryAsp:${secondaryAsp}.")
    def aspStruct = secondaryAsp.prepareEmptyRow()//type is "com.quest.nitro.service.sl.interfaces.config.IAspStruct"
	aspStruct.setValueByString("lmdIgnoreName", ignore_filterName)
	aspStruct.setValueByString("lmdIgnoreIsEnabled", "true")
	aspStruct.setValueByString("lmdIgnoreColumn", ignore_fieldName)
	aspStruct.setValueByString("lmdIgnoreExpression", ignore_expression)
	log("addRowItem: ignore_filterName:${ignore_filterName}, ignore_fieldName:${ignore_fieldName}, ignore_expression:${ignore_expression}.")
	secondaryAsp.appendRow(aspStruct)
	configService.saveConfig(secondaryAsp)
	log("addRowItem: save the row into secondaryAsp:${secondaryAsp} successfully.")
	log("")
}
def getIgnoreListKnownNames() {
	def knownNames = configService.getKnownNamesForSharingName("DB_DB2", "DB_DB2", IGNORE_LIST_GROUP_ID).toList(); //Get sharing Groups
	return knownNames
}

def log(content) {
	println content
	output.append(content).append("\n")
}

STATUS

A new Enhancement ID FOGGENERAL-I-124 has been created to add new match and ignore list entries to all agents as an option in the product for different database agent types. This will be considered by Product Management for a future release of the Foglight for Database cartridges.